The applet requires Java 5 or higher. Java must be enabled in your browser settings. Mac users must have Mac OS X 10.4 or higher. Windows and Linux users may obtain the latest Java from Oracle's Java site.

powered by NetLogo

view/download model file: vot1.nlogo

WHAT IS IT?

Una primera entrega d’un model que intenta examinar com afecten diversos factors la decisió de vot individual entre unionisme i independentisme

HOW IT WORKS

Primer de tot fem una distribució aleatòria de 1023 individus (31x33 quadrets) entre unionistes (blaus, vot 0) i independentistes (vermells, vot 1).
Establim nivells d’enuig i temor a partir de diversos paràmetres (greuge-percebut, legitimitat-constitució, aversió-risc, probabilitat-catàstrofe) situats entre 0-1
Establim un nivell de vot sobiranista inicial
Establim un nivell d’enuig donat per: enuig = greuge-percebut * (1 - legitimitat-constitució)
Establim un nivell de temor donat per: temor = aversió-risc * probabilitat-catàstrofe.
Fem una distribució normal de enuig-temor entre els individus
Si enuig > temor per més de 0,1 considerem que l'individu és favorable a la consulta.
Mirem la intenció de vot dels veïns. cada subjecte té 8 veïns, limita amb vuit quadrets. Si hi ha una majoria d'almenys 7/8 de veïns que voten una alternativa, el subjecte vota aquesta alternativa.
Si son 6/8 parts favorables a l'independentisme i enuig > temor, vota sí-sí.  Si són 6/8 favorables a l'unionisme (2/8) i enuig < temor, vota no.
Si són 5/8 parts favorables a l'independentisme i enuig - temor > 0.1, vota sí-sí. Si són 5/8 favorables a l'unionisme (3/8) i enuig - temor < -0.1, vota no.
Si hi ha empat a 4/8 parts només vota sí-sí quan enuig > temor per més de 0,2; i vota no quan enuig-temor < -0.2. 
Si només són 1/8 parts favorables a l'independentisme, només vota sí-sí quan enuig > temor per més de 0,5 i activem el puls del sobiranisme.
El model evoluciona en el temps (ticks)

HOW TO USE IT

Primer col·loquem el botó lliscant central-superior a ‘slower’.
A continuació situem els diversos paràmetres (greuge-percebut, legitimitat-constitució, aversió-risc, probabilitat-catàstrofe) als valors entre 0-1 que volguem examinar.
Donem un valor incial al percentage del sobiranisme.
Premem [setup], premem [go]. Per aturar tornem a premer [go].
Podeu repetir el procés quantes vegades volgueu: paràmetres, setup, go, go.

THINGS TO NOTICE

La gent apareix progressivament homogèniament agrupada en zones de territori i arriba un moment que s’estabilitza la intenció de vot. Veiem també que petites variacions dels paràmetres poden donar resultats molt diferents, el model és molt sensible a aquestes petites variacions. Segurament perquè el model és massa simple, però també pot reflectir una circumstància real del procés: no està guanyat

THINGS TO TRY

move sliders, switches, etc. i examineu els afectes que tenen sobre el territori

EXTENDING THE MODEL

Quins factors socials determinen els paràmetres greuge-percebut, legitimitat-constitució, aversió-risc, probabilitat-catàstrofe i com afecten els diversos individus?. En el model són fixats exteriorment pel propi observador-usuari

CREDITS AND REFERENCES

Basat en els models ‘Voting’ i ‘Rebellion’ de la llibreria que acompanya el NetLogo.

CODE

globals [
    threshold           ; by how much must enuig > temor to make someone rebel?
    consulta?           ;; if true, then active
    balanç              ;; diferència global enuig-temor
    n_aleatori          ;; número aleatori 0-100
]

patches-own [
  vote   ;; my vote (0 or 1)
  total  ;; sum of votes around me
  pbalanç   ;; enuig-temor individual segons la normal per patch
]

to setup
  clear-all
  set threshold 0.1
  set consulta? (enuig - temor > threshold)
  set balanç (enuig - temor)
  ask patches [
      set n_aleatori random 100
      ifelse n_aleatori <= sobiranisme-%-inicial [set vote 1] [set vote 0]
      set pbalanç random-normal balanç abs (balanç / 2)  ;; distribució normal (mitjana desviació)
      recolor-patch 
  ]
  reset-ticks
end

to recolor-patch  ;; patch procedure
  ifelse vote = 0
    [ set pcolor blue ]
    [ set pcolor red ]
end

to-report enuig
  report greuge-percebut * (1 - legitimitat-constitució)
end
 
to-report temor
  report aversió-risc * probabilitat-catàstrofe
end

to go
  ask patches
    [ set total (sum [vote] of neighbors) ]
  ;; use two ask patches blocks so all patches compute "total"
  ;; before any patches change their votes
  
  ask patches
    [ if total > 6 [ set vote 1 ]
      if total < 2 [ set vote 0 ]
      if (total = 6) and (pbalanç > 0) [ set vote 1 ]
      if (total = 2) and (pbalanç < 0) [ set vote 0 ]  
      if (total = 5) and (pbalanç > 0.1) [ set vote 1 ] 
      if (total = 3) and (pbalanç < -0.1) [ set vote 0 ]   
      if (total = 4) and (pbalanç > 0.2) [ set vote 1 ]
      if (total = 4) and (pbalanç < -0.2) [ set vote 0 ]
      if (total = 1) 
          [ifelse adjudicar-plus-sobiranisme? and (pbalanç > 0.5)
              [ set vote 1 ]
              [ set vote 0 ] ]
      recolor-patch ]
  tick
end